특수한 경우

우변에 시차종속변수가 등장하지 않는 모형

예를 들어 성장모형 \(g_{it} = \alpha + \rho \ln y_{it-1} + \mathbf{x}_{it} \beta + \delta_t + \mu_i + \varepsilon_{it}\)
- \(g_{it}\)는 성장률, \(y_{it}\)는 GDP
- 우변에 \(g_{it-1}\)이 없음에 유의
- Stata의 xtabond나 xtdpdsys로써 추정할 수 없음. lags(0) 옵션 작동하지 않음

해결책 1: 모형 변환 방법

\(g_{it} = \Delta \ln y_{it}\)임을 이용하여 모형을 \(\ln y_{it} = \alpha + (1+\rho) \ln y_{it-1} + X_{it} \gamma + \mu_i + \varepsilon_{it}\)로 변환
단, 모수가 \(\rho\)에서 \(1+\rho\)로 바뀐다는 점이 번거로움

growth-ex.dta 자료에 대하여 \(g_{it} = \alpha + \rho \ln y_{it-1} + \beta_1 x_{1,it} + \beta_2 x_{2,it} + \beta_3 x_{3,it} + \delta_t + \mu_i + \varepsilon_{it}\), \(g_{it} = \Delta \ln y_{it}\) 모형을 DPD 모형으로 변환시킨 후 2단계(two 옵션) 시스템적률법을 이용하여 추정하라(x1은 외생적, x2는 선결적, x3은 내생적). 견고한 표준오차(vce(r))를 이용하라. 변환된 모형에서 \(\ln y_{it-1}\)의 계수 추정치(\(1+\rho\)에 해당)는 얼마인가? 변환 이전 원래 추정식(좌변에 성장률이 있는 식)의 \(\rho\) 계수 추정값은 얼마인가(di 명령을 이용하여 1을 뺄 것)? 결과를 이용하여 \(H_0:\rho=0\)을 검정하라(\(\hat\gamma-1\)의 표준오차는 \(\hat\gamma\)의 표준오차와 동일함을 이용). 결과 확인: Stata에서 L.lny의 계수 추정값(\(1+\rho\)에 해당)은 .488078이며 견고한 표준오차는 .0593504.

코드 보기

use growth-ex, clear
qui tab year, gen(yr)
xtdpdsys lny x1 yr3-yr11, pre(x2) endo(x3) two vce(r)
di .488078-1
di (.488078-1)/.0593504

위 실습에서 시간 더미를 어디까지 넣어야 하는지는 늘 혼란스럽다. yr3-yr11 대신에 yr2-yr11을 사용하면 어떤 결과를 얻는가? yr4-yr11을 사용하면? 실제 분석 시에는 어떻게 하는 것이 좋겠는가?

위에서는 \(g_{it}= \Delta \ln y_{it}\)이므로 모형변환 방법을 사용할 수 있었다. 만약 성장률을 통상적인 방법대로 \(g_{it} = (\Delta y_{it}) / y_{it-1}\)이라고 정의한다면 모형변환 방법을 사용할 수 있겠는가?

해결책 2: xtdpd

Difference GMM의 경우 다음 두 명령은 동일함

xtabond lny x1 yr3-yr11, pre(x2) endo(x3) vce(r)
xtdpd l(0/1).lny x1 x2 x3 yr3-yr11, ///
    dgmm(x2, lag(1 .)) dgmm(lny x3) div(x1 yr3-yr11) hascons vce(r)

growth-ex.dta 데이터에서 위 두 명령의 결과가 전적으로 동일한지 확인하라. 특히 결과 중 “Instruments” 부분을 서로 비교하여 양자가 동일함을 확인하라.

코드 보기

use growth-ex, clear
tab year, gen(yr)
xtabond lny x1 yr3-yr11, pre(x2) endo(x3) vce(r)
xtdpd l(0/1).lny x1 x2 x3 yr3-yr11, dgmm(x2, lag(1 .)) dgmm(lny x3) div(x1 yr3-yr11) hascons vce(r)

System GMM의 경우 다음 두 명령은 동일함

xtdpdsys y x1, pre(x2) endo(x3) vce(r)
xtdpd l(0/1).y x1 x2 x3 yr3-yr11, ///
    dgmm(x2, lag(1 .)) dgmm(y x3) div(x1) ///
    lgmm(x2, lag(0)) lgmm(y x3) hascons vce(r)

growth-ex.dta 데이터에서 위 두 명령의 결과가 전적으로 동일한지 확인하라. 특히 결과 중 “Instruments” 부분을 서로 비교하여 양자가 동일함을 확인하라.

코드 보기

use growth-ex, clear
tab year, gen(yr)
xtdpdsys lny x1 yr3-yr11, pre(x2) endo(x3) vce(r)
xtdpd l(0/1).lny x1 x2 x3 yr3-yr11, dgmm(x2, lag(1 .)) dgmm(lny x3) div(x1 yr3-yr11) lgmm(x2, lag(0)) lgmm(lny x3) hascons vce(r)

그러므로 xtabond와 xtdpdsys 명령 대신 xtdpd 명령을 사용하여 ‘반자동’으로 추정할 수 있음
- 이때 l(0/1).y 부분을 수정하면 됨

앞에서 고려한 변환 이전 원래 모형의 \(\rho\)를 2단계 효율적 시스템적률법으로 추정하고자 한다(\(1+\rho\)가 아니라). 좌변에 growth 변수를 사용하고 xtdpd 명령을 사용하여 결과를 구하라. 이 값은 앞에서 구한 \(\gamma-1\) 추정값과 동일한가? “\(\rho=0\)”에 해당하는 검정통계량 값은 얼마인가? 이 값은 앞에서 구한 값과 동일한가?

코드 보기

use growth-ex, clear
tab year, gen(yr)
xtdpd growth l.lny x1 x2 x3 yr3-yr11, dgmm(x2, lag(1 .)) dgmm(lny x3) div(x1 yr3-yr11) lgmm(x2, lag(0)) lgmm(lny x3) hascons two vce(r)
* rhohat = -.511922

해결책 3: xtabond2

Difference GMM의 경우 다음 두 명령은 동일함

xtabond lny x1 yr3-yr11, pre(x2) endo(x3) vce(r)
xtabond2 l(0/1).lny x1 x2 x3 yr3-yr11, gmm(x2 l.(lny x3)) iv(x1 yr3-yr11) noleveleq r

growth-ex.dta 데이터에서 위 두 명령의 결과가 동일한지 확인하라. 특히 결과 중 “Instruments” 부분을 서로 비교하여 양자가 동일함을 확인하라. two 옵션을 주면 서로 달라질 수 있는데 불분명함.

System GMM의 경우 다음 두 명령은 동일함

xtdpdsys lny x1 yr3-yr11, pre(x2) endo(x3) vce(r)
xtabond2 l(0/1).lny x1 x2 x3 yr3-yr11, gmm(x2 l.(lny x3)) iv(x1 yr3-yr11, eq(d)) h(2) r

growth-ex.dta 데이터에서 위 두 명령의 결과가 동일한지 확인하라. 특히 결과 중 “Instruments” 부분을 서로 비교하여 양자가 동일함을 확인하라. 두 명령에 모두 two 옵션을 붙여 두 결과가 동일한지 살펴보라.

이상을 이용하면 우변에 종속변수 래그가 없는 동태적 패널모형도 xtabond2로써 모형 부분을 수정하여 추정할 수 있음

원래 모형의 \(\rho\)를 xtabond2의 two-step 시스템GMM으로 추정하고자 한다(\(1+\rho\)가 아니라). 좌변에 growth 변수를 사용하고 xtabond2 명령을 사용하여 결과를 구하라. (2단계 효율적 추정을 위해서는 마지막에 two 옵션을 사용하라.) 이 값은 앞에서 구한 \(\beta\) 추정값과 동일한가? “\(\rho=0\)”에 해당하는 검정통계량 값은 얼마인가? 이 값은 위에서 구한 값과 동일한가?

코드 보기

use growth-ex, clear
tab year, gen(yr)
xtabond2 growth l.lny x1 x2 x3 yr3-yr11, gmm(x2 l.(lny x3)) iv(x1 yr3-yr11, eq(d)) h(2) two r
* rhohat = -.511922