동적 패널 프로빗

• 우변에 \(y_{it-1}\)이 있는 동태적 패널 프로빗 모형은 Wooldridge (2005)의 CRE 방법을 사용하면 간편하게 추정할 수 있음
• 우변에 CRE 방식으로 \(\mu_i\)의 평균을 결정하는 외생변수들(\(\bar{\mathbf{x}}_i\)나 \(\mathbf{x}_{i1}, \ldots, \mathbf{x}_{iT}\)나 여타 변수들)과 \(y_{i0}\)을 추가한 후 RE 프로빗 추정을 함

vv98.dta 자료를 이용한다. 모형은 \(union_{it} = 1\{ \gamma_t + \beta mar_{it} + \alpha union_{it-1} + \mu_i + \varepsilon_{it}>0 \}\). 시간 더미가 포함되어 있음에 유의하라. \(\mu_i\)가 모든 시기의 mar, union의 초기값, school, black에 의존하는 동태적 CRE 프로빗 모형을 “xtprobit, re” 명령을 이용하여 추정하라. 참고로, time-invariant한 school과 black이 union 결정모형에는 없고 \(\mu_i\)의 평균을 결정하는 것으로 되어 있으나, 이 시불변 변수들이 union 결정모형에 포함되어 있다고 해도 추정모형은 동일하다. 시불변 변수들이 종속변수를 설명하는지 \(\mu_i\)를 설명하는지는 중요하지 않다.

코드 보기

use vv98, clear
xtset
tab year
by nr: egen union_1980 = total(union / (year==1980)), missing
forv k=1981/1987 {
  by nr: egen mar_`k' = total(mar / (year==`k')), missing
}
xtprobit union mar l.union union_1980 mar_* school black i.year, re
* coef on mar = .168908, L1.union = .8975104

lfp.dta 자료를 사용하라. 피설명변수는 \(\mathit{lfp}_{it}\), 설명변수는 \(\mathit{lfp}_{it-1}\), \(kids_{it}\), \(lhinc_{it}\), \(educ_i\), \(black_i\), \(age_i\), \(agesq_i\)이고 기간 더미들을 포함한다. \(\mathit{lfp}_{i1}\) (최초 시점), \(kids_{i2}\), ..., \(kids_{i5}\), \(lhinc_{i2}\), ..., \(lhinc_{i5}\)를 설명변수로 추가하는 CRE 프로빗 회귀를 하라.

코드 보기

use lfp, clear
xtset
xtsum
by id: egen lfp1 = total(lfp/(period==1)), missing
foreach v of varlist kids lhinc {
  forv k=2/5 {
    by id: egen `v'_`k' = total(`v'/(period==`k')), missing
  }
}
xtprobit lfp l.lfp kids lhinc educ black age agesq lfp1 kids_* lhinc_* i.period, re
* coef on l.lfp = 1.543212, kids = -.1451527